Nhập/xuất dữ liệu với Free Pascal trong lập trình thi đấu

u Code

Trong các kỳ thi học sinh giỏi tin học và các giải lập trình thi đấu, Free Pascal vẫn là một trong ngôn ngữ chính thức và đôi khi là ngôn ngữ bắt buộc trong các kỳ thi ở cấp nhỏ (THCS). Bài viết này hướng dẫn cách nhập/xuất dữ liệu với Free Pascal trong các kỳ thi, cũng như trong quá trình làm bài tập hàng ngày của mọi người.

Có hai hình thức nhập xuất dữ liệu chính thường được yêu cầu trong các kỳ thi, bao gồm:

  • Nhập (đọc) dữ liệu từ stdin (mặc đình là bàn phím) và xuất (ghi) dữ liệu ra stdout (mặc định là màn hình)
  • Đọc/ghi dữ liệu từ tập tin văn bản (text file)

Nhập (đọc) dữ liệu từ bàn phím

Đây là chế độ nhập dữ liệu trong hầu hết các hệ thống chấm bài online. Việc nhập dữ liệu được thực hiện bởi hai thủ tục readreadln. Khi chạy trên máy tính cá nhân, gặp câu lệnh nhập dữ liệu này, chương trình sẽ dừng lại để ta nhập dữ liệu vào từ bàn phím, bấm Enter để kết thúc một thao tác nhập liệu.

Thông tin thêm: trong chế độ chấm, hệ thống chấm bài sẽ không hoạt động như vậy, nó sẽ chuyển hướng stdin để lấy dữ liệu từ file chứa dữ liệu test thay vì dừng lại chờ nhập dữ liệu bằng tay.

  • Thủ tục read(danh_sách_biến);readln(danh_sách_biến); đều nhập giá trị ngăn cách nhau với một hoặc nhiểu khoảng trống và gán lần lượt cho các biến trong danh_sách_biến.
  • Điểm khác nhau giữa Thủ tục readreadln là sau khi thực hiện việc nhập liệu, lệnh readln sẽ chuyển xuống dòng dưới, bỏ qua các giá trị còn lại trên dòng hiện tại, lệnh read thì không.
  • Trong cả hai trường hợp dùng read hoặc readln, nếu dòng hiện tại không đủ dữ liệu để gán cho danh_sách_biến, chúng sẽ tiến hành đọc tiếp ở các dòng tiếp theo.

Xét ví dụ sau:

var a, b, c: int64;
begin
    readln(a, b);
    readln(c);
    writeln(a, ' ', b, ' ', c);
end.

Nếu nhập vào dữ liệu như sau:

1 2 3
4

Thì kết quả sẽ được a=1,b=2a = 1, b = 2c=4c = 4 (giá trị 33 bị bỏ qua bởi thủ tục readln đầu tiên.

Nếu nhập vào dữ liệu như sau:

1
2
3

Thì kết quả sẽ được a=1,b=2a = 1, b = 2c=3c = 3 (thủ tục readln đầu tiên đọc dữ liệu trên cả hai dòng đầu, do dòng đầu tiên không đủ dữ liệu).

Nhập dữ liệu dạng xâu ký tự (string)

Đối với biến kiểu xâu ký tự, lệnh readreadln luôn đọc cả dòng dữ liệu và gán cho xâu (không tách theo khoảng trống như ví dụ trên).

Xét ví dụ sau:

var s: string;
begin
    readln(s);
    writeln(s)
end.

Với nhập vào dữ liệu như sau:

Hello Pascal from Thuc

Xâu s sẽ được gán giá trị cả dòng dữ liệu này: s = 'Hello Pascal from Thuc'.

Nếu nhập hai xâu trên một dòng, xâu thứ nhất sẽ chứa toàn bộ dòng, xâu thứ hai sẽ rỗng.

var s1, s2 : string;
begin
    readln(s1, s2);
    writeln(s1, ' ---- ', s2)
end.

Với nhập vào dữ liệu như sau:

Hello Pascal from Thuc

Xâu s sẽ được gán giá trị cả dòng dữ liệu này: s = 'Hello Pascal from Thuc', s2 = '', chương trình sẽ in ra:

hello Pascal from Thuc ----

Lưu ý: Kiểu dữ liệu string trong Free Pascal mặc định là ShortString, với độ dài tối đa là 255 ký tự. Với ví dụ trên, nếu dòng nhập vào có nhiều hơn 255 ký tự thì 255 ký tự đầu sẽ được gán cho s1, phần còn lại sẽ được gán cho s2 (cũng tối đa 255 ký tự). Để nhập vào xâu ký tự dài hơn 255 ký tự, ta cần sử dụng kiểu dữ liệu AnsiString thay vì String mặc định.

Xuất (ghi) dữ liệu ra màn hình

Tương tự, đây là chế độ xuất dữ liệu trong hầu hết các hệ thống chấm bài online. Việc nhập dữ liệu được thực hiện bởi hai thủ tục writewriteln.

  • Thủ tục write(danh_sách_giá_trị);writeln(danh_sách_giá_trị); đều xuất (ghi, in) các giá trị trong danh_sách_giá_trị, không có khoảng trống ở giữa. Ở đây, danh_sách_giá_trị có thể là danh sách các hằng, các biến, các biểu thức hoặc hỗn hợp giữa chúng.
  • Điểm khác nhau giữa Thủ tục writewriteln là sau khi thực hiện việc xuất dữ liệu, lệnh writeln sẽ viết thêm một dấu xuống dòng để chuyển xuống dòng dưới (các lệnh xuất dữ liệu tiếp theo sẽ ghi từ dòng bên dưới dòng hiện tại). Còn với lệnh write thì các lệnh xuất dữ liệu tiếp theo sẽ ghi dữ liệu tiếp vào cuối dòng hiện tại.

Xét chương trình sau:

var a, b, c: int64;
begin
    a := 2;
    b := 3;
    writeln('Ket qua: ', a, ' + ', b, ' = ', a+b);
end.

Kết quả thực thi chương trình trên sẽ như sau:

Ket qua: 2 + 3 = 5

Nhập/xuất dữ liệu từ file văn bản

Đây là chế độ nhập dữ liệu thường gặp trong các kỳ thi học sinh giỏi trong chương trình phổ thông, trong đó dữ liệu nhập vào được ghi sẵn trong một file văn bản (text file), các file này có thể được soạn thảo bằng các ứng dụng soạn thảo văn bản như Notepad, Notepad++, và thường có phần mở rộng là .txt, hoặc cũng có thể soạn sảo trực tiếp bằng Free Pascal IDE.

Trong quá trình học và thực hành, hình thức nhập dữ liệu từ file văn bản cũng thường được dùng để tránh việc phải nhập đi nhập lại các dữ liệu đầu vào khi phải chạy thử chương trình nhiều lần lúc lập trình, nhất là với những bài có dữ liệu vào nhiều và phức tạp.

Trước khi làm việc với file, cần đảm bảo chắc chắn bạn nắm rõ mình đang làm việc ở thư mục nào, file dữ liệu được đọc/ghi sẽ nằm ở đâu trên ổ đĩa cứng và file chương trình (.pas) sẽ nằm ở đâu. (Xem phần Chuyển thư mục làm việc trong Free Pascal bên dưới)

Các bước để nhập/xuất dữ liệu từ file văn bản như sau:

  1. Khai báo biến file có kiểu là text, thông thường ta sẽ cần hai biến, một biến cho file input (để nhập dữ liệu) và một biến cho file output (để xuất dữ liệu)
var fi, fo: text;
  1. Gán biến file cho một đường dẫn đến file sẽ đọc/ghi với lệnh assign. Nếu đường dẫn chỉ gồm tên file thì file này sẽ nắm trong thư mục hiện hành (Xem phần Chuyển thư mục làm việc trong Free Pascal bên dưới).
assign(fi, 'input.txt');
assign(fo, 'output.txt');
  1. Mở file để đọc với lệnh reset, hoặc mở file để ghi với lệnh rewrite:
reset(fi);
rewrite(fo);
  1. Tiến hành đọc/ghi với lệnh read/readlnwrite/writeln giống như ở trên, chỉ thêm tham số đầu tiên là tên biến file cần đọc/ghi
readln(fi, a, b);
writeln(fo, 'Ket qua: ', a, ' + ', b, ' = ', a+b);

Lưu ý:

  • Khi đọc từ file, file cần phải tồn tại nếu không sẽ báo lỗi.
  • Khi ghi file, file trùng tên nếu đã tồn tại sẽ bị ghi đè.
  1. Đóng file sau khi đọc/ghi. Thao tác này hết sức quan trọng nhưng lại hay bị quên. Việc quên đóng file sau khi ghi có thể dẫn đến việc dữ liệu file bị thiếu. Để đóng file, ta dùng lệnh close:
close(fi);
close(fo);

Toàn bộ chương trình như sau:

var fi, fo: text;
    a, b, c: int64;
begin
    assign(fi, 'input.txt');
    assign(fo, 'output.txt');
    reset(fi);
    rewrite(fo);
    readln(fi, a, b);
    writeln(fo, 'Ket qua: ', a, ' + ', b, ' = ', a+b);
    close(fi);
    close(fo);
end.

Để chạy chương trình, ta tạo file input.txt ở cạnh file chương trình (.pas) bằng Notepad và gõ vào hai số nguyên nào đó, rồi ghi file lại. Chạy chương trình bằng tổ hợp phím Ctrl+F9, ta sẽ thấy file output.txt được tạo ra, mở file này ta sẽ thấy kết quả mà chương trình ghi ra.

Courses

Tags

Blog

Tags

About

uCode offers interactive Python, Scratch, C/C++, Algorithms, Pascal, Web, Game. Mobile App… courses for everyone from primary students to adults. Learn from a team of expert teachers in the comfort of your browser with video lessons and fun coding challenges and projects